TITLE AMPA

COMMENT
AMPA model from;
Hübel N, Hosseini-Zare MS, Žiburkus J, Ullah G (2017) The role of glutamate in neuronal ion homeostasis: A case study of spreading depolarization. (ModelDB: 235774)
ENDCOMMENT

NEURON {
    SUFFIX ampa 
    USEION k READ ek WRITE ik
    USEION na READ ena WRITE ina
    USEION glu READ glui
    RANGE ik, ina, itot, gbar, r, accna, acck
}

UNITS
{
    (mV) = (millivolt)
    (mA) = (milliamp)
    (S)  = (siemens)
    (um) = (micrometers)
    (molar) =  (1/liter)
    (mM) = (millimolar)
}

ASSIGNED {
    ik (mA/cm2)
    ina (mA/cm2)
    itot (mA/cm2)
    ek (mV)
    ena (mV)
    eca (mV)
    glui (mM)   : glutamate concentration in the cleft
    area (um2)
    g (S/cm2)
    v (mV)
    accna (mA/cm2)
    acck (mA/cm2)
}

STATE
{
    r (1) : proportion of bound receptors
}

PARAMETER {
    alpha = 1.1 (1/mM ms)
    beta = 0.19 (1/ms)
    gbar = 0.486e-3 (S/cm2)
    dsyn = 0.2777777777777778 : density of synapses (1/um2)
    mg = 1.2 (mM)
    
    : additional parameters to correct the units 
    mgscale = 3.0 (mM)
    vbar = 1.0 (mV)
}


BREAKPOINT {
    SOLVE binding METHOD cnexp
    ik = g * r * (v - ek)/(1 + (mg/mgscale)*exp((-0.07*v - 0.7)/vbar))
    ina = g * r * (v - ena)/(1 + (mg/mgscale)*exp((-0.07*v - 0.7)/vbar))
    itot = ik + ina
    acck = acck + ik
    accna = accna + ina
}

INITIAL {
    r = 0 : 0.0001447158963834182   : gli = 25e-6 
    g =  dsyn * gbar / (50000.0/180000.0)  : gbar based on total of 50,000 synapses
    acck = 0
    accna = 0
}

DERIVATIVE binding 
{
    r' = glui * alpha * (1-r) - beta*r
}