TITLE mglur 

NEURON {
    SUFFIX mglur 
    USEION glu READ gluo VALENCE -1
    USEION ip3 WRITE iip3 VALENCE 1
    NONSPECIFIC_CURRENT i
    RANGE totalmGluR, GlumGluR, mGluR, r, i, iip3, K2
}

UNITS
{
    (molar) =  (1/liter)
    (mM) = (millimolar)
    (um) = (micron)
    (mA) = (milliamp)
    (mV) = (millivolt)
    FARADAY = (faraday) (coulomb)
}

ASSIGNED {
    gluo (mM)
    vol (um3)
    diam (um)
    area (um2)
    iip3 (mA/cm2)
    i (mA/cm2)
}

STATE
{
    mGluR (mM)
    GlumGluR (mM)
}

PARAMETER {
      totalmGluR = 30e-3 (mM)
      K1 = 280 (/ms mM)	: forward binding rate to receptor from Bhalla et al
      K2 = 0.016 (/ms)
      r = 0.2083e-3 (1): proportion of bindings that result in ip3 production
                       : given a clearance rate of 1/1000 if all mGluR are bound
                       : this gives steady-state ip3 of 100nm
}


BREAKPOINT {
    SOLVE bindkin METHOD sparse
    iip3 = -(1e-4) * r * (K2 * FARADAY * GlumGluR * vol/area)
    i = -iip3
}

KINETIC bindkin { 
  ~ gluo + mGluR <-> GlumGluR (K1, K2)
    CONSERVE mGluR + GlumGluR = totalmGluR
}

INITIAL {
                        : changed basal gluo to 0
    mGluR = totalmGluR  : - K1*25e-6*totalmGluR/(K2 + K1*25e-6)
    GlumGluR = 0        : K1*25e-6*totalmGluR/(K2 + K1*25e-6)
    vol = area * diam
}