TITLE NMDA

COMMENT
NMDA model from;
Hübel N, Hosseini-Zare MS, Žiburkus J, Ullah G (2017) The role of glutamate in neuronal ion homeostasis: A case study of spreading depolarization. (ModelDB: 235774)
Addition of ica with scaleca parameter based on 
Somjen GG, Kager H, Wadman WJ (2008) Computer simulations of neuron-glia interactions mediated by ion flux. (ModelDB: 113446)
ENDCOMMENT



NEURON {
    SUFFIX nmda 
    USEION k READ ek WRITE ik
    USEION na READ ena WRITE ina
    USEION ca READ eca WRITE ica
    USEION glu READ glui
    RANGE ik, ina, ica, itot, gbar, r, acck, accna, accca
}

UNITS
{
    (mV) = (millivolt)
    (mA) = (milliamp)
    (S)  = (siemens)
    (um) = (micrometers)
    (molar) =  (1/liter)
    (mM) = (millimolar)
}

ASSIGNED {
    ik (mA/cm2)
    ica (mA/cm2)
    ina (mA/cm2)
    accca (mA/cm2)
    accna (mA/cm2)
    acck  (mA/cm2)
    itot (mA/cm2)
    ek (mV)
    ena (mV)
    eca (mV)
    glui (mM)   : glutamate concentration in the cleft
    area (um2)
    g (S/cm2)
    v (mV)
}

STATE
{
    r (1) : proportion of bound receptors
}

PARAMETER {
    alpha = 0.072 (1/mM ms)
    beta = 0.0066 (1/ms)
    gbar = 0.139e-3 (S/cm2)
    dsyn = 0.2777777777777778 : density of synapses (50000/180000) (1/um2)
    vbar = 1.0 (mV)
    
    mg = 1.2 (mM)
    mgscale = 3.0 (mM)
    scaleca = 1
}


BREAKPOINT {
    SOLVE binding METHOD cnexp
    ik = g * r * (v - ek)/(1 + (mg/mgscale)*exp((-0.07*v - 0.7)/vbar))
    ina = g * r * (v - ena)/(1 + (mg/mgscale)*exp((-0.07*v - 0.7)/vbar))
    ica =  g * scaleca * r * (v - eca)/(1 + (mg/mgscale)*exp((-0.07*v - 0.7)/vbar))
    itot = ik + ina + ica
    acck = acck + ik
    accca = accca + ica
    accna = accna + ina
}

INITIAL {
    r = 0 : 0.0002726529128419522 : gli = 25e-6 
    g = dsyn * gbar / (50000.0/180000.0)  :  gbar based on total of 50,000 synapses
    acck = 0
    accna = 0
    accca = 0
}

DERIVATIVE binding 
{
    r' =  glui * alpha * (1-r) - beta*r
}