TITLE n-calcium channel
: n-type calcium channel
: Tuomo 2023:
: -Changed GHK formalism to a simpler multiplication by membrane potential minus reversal potential. Included eca in the READ block.
: -Parametrized the half-activation and half-inactivation voltages

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)

	FARADAY = 96520 (coul)
	R = 8.3134 (joule/degC)
	KTOMV = .0853 (mV/degC)
}

PARAMETER {
	v (mV)
	celsius 		(degC)
	gcanbar=.0003 (mho/cm2)
	ki=.001 (mM)
	cai=50.e-6 (mM)
	cao = 2  (mM)
	q10=5
	mmin = 0.2
	hmin = 3
	a0m =0.03
	zetam = 2
	vhalfm = -14
	gmm=0.1
	offma = 19.88
	offmb = 0.0
	offha = 0.0
	offhb = 39.0
	
}


NEURON {
	SUFFIX CaNtype
	USEION ca READ eca, cai WRITE ica
        RANGE gcanbar, ica, gcan       
        GLOBAL hinf,minf,taum,tauh
}

STATE {
	m h 
}

ASSIGNED {
	ica (mA/cm2)
	eca (mV)
        gcan  (mho/cm2) 
        minf
        hinf
        taum
        tauh
}

INITIAL {
        rates(v)
        m = minf
        h = hinf
}

BREAKPOINT {
	SOLVE states METHOD cnexp
	gcan = gcanbar*m*m*h*h2(cai)
	ica = gcan*(v-eca)

}

UNITSOFF
FUNCTION h2(cai(mM)) {
	h2 = ki/(ki+cai)
}


FUNCTION alph(v(mV)) {
	alph = 1.6e-4*exp((offha-v)/48.4)
}

FUNCTION beth(v(mV)) {
	beth = 1/(exp((offhb-v)/10.)+1.)
}

FUNCTION alpm(v(mV)) {
	alpm = 0.1967*(offma-v)/(exp((offma-v)/10.0)-1.0)
}

FUNCTION betm(v(mV)) {
	betm = 0.046*exp((offmb-v)/20.73)
}

FUNCTION alpmt(v(mV)) {
  alpmt = exp(0.0378*zetam*(v-vhalfm)) 
}

FUNCTION betmt(v(mV)) {
  betmt = exp(0.0378*zetam*gmm*(v-vhalfm)) 
}

UNITSON

DERIVATIVE states {     : exact when v held constant; integrates over dt step
        rates(v)
        m' = (minf - m)/taum
        h' = (hinf - h)/tauh
}

PROCEDURE rates(v (mV)) { :callable from hoc
        LOCAL a, b, qt
        qt=q10^((celsius-25)/10)
        a = alpm(v)
        b = 1/(a + betm(v))
        minf = a*b
	taum = betmt(v)/(qt*a0m*(1+alpmt(v)))
	if (taum<mmin/qt) {taum=mmin/qt}
        a = alph(v)
        b = 1/(a + beth(v))
        hinf = a*b
:	tauh=b/qt
	tauh= 80
	if (tauh<hmin) {tauh=hmin}
}